#TRACE/LINKS/STATS BEAUTIFYING SCRIPT 
#(modified by TG!cedras@rahul.net)
###############################
# TRACE 
###############################
# FOR THE USE OF /TRACE , you have the option of seeing users on a
# server or not:  ESC-t turns this option on and off.
# It also effects the output of STAT l
# SEEING USERS ON A SERVER IS AN OPERATOR PRIVILEDGE :p
#
#SOME SPECIAL FORMATING ALIASES (SIO TAKES CREDIT FOR MOST OF EM)
alias sname {
	if (tmp = index(\[ $0))
		{@function_return = left($tmp $0)}
		{@function_return = [$0]}
}
 
alias sip{
	if (tmp = index(\[ $0))
		{@function_return = right($tmp $0)}
		{@function_return = [$0]}
}
 
on ^206 * echo *** $1 \[$[-6]2\] ==> $3 $4 $stu($sname($5))$sip($5) $stu($6) $7-
 
alias stu {
	if ([$right(13 $0)] == [.undernet.org]) {
		@tmp = left($rindex(. $0) $0)
		@function_return = left($rindex(. $tmp) $tmp)
	} { @function_return = [$0] }
}
 
 
#Users seen by default: 
^assign trace x
 
#Make ESC-t the toggle combination keys
^bind meta1-t parse_command tt
 
^alias tt if (trace) { assign -trace } { assign trace x }
 
###TRACEING
alias TRACE ^cleantr;^assign _tn $0;^assign _tt Trace:$left($index(. $S)-1 $S);quote trace $0-
 
on ^server_notice *LINK* comment
on ^200 * assign _tt $_tt-$left($index(. $0)-1 $0)
on ^NOTICE "*.* *LINK*" assign _tt $_tt-$left($index(. $3)-1 $3)
 
on ^notice "*.* *OPER*" {
	if ( [$6] )
		{ assign _tx $6 }
		{ assign _tx $5 }
	if ( rmatch($left($index([ $_tx)-1 $_tx) $_tn) == 1 )
		{ _trace_parse $0 $_tx * }
		{ _trace_servb $* }
	assign -_tx
}
on ^notice "*.* *USER*" {
	if ( [$6] )
		{ assign _tx $6 }
		{ assign _tx $5 }
	if ( rmatch($left($index([ $_tx)-1 $_tx) $_tn) == 1 )
		{ _trace_parse $0 $_tx }
		{ _trace_servb $* }
	assign -_tx
}
on ^notice "%.% *SERV*" _trace_servb $*
alias _trace_servb {
	if ( rmatch($0 $_tn) == 1 )
		{ echo $_tt-$0 }
	assign -_tt
	assign -_tr
	assign _tn qwertyuipoadfg
	echo $1-3 $5-
}
on ^204 * {
	if ( rmatch($left($index([ $3)-1 $3) $_tn) == 1 )
		{ _trace_parse $0 $3 * }
		{ _trace_serva $* }
echo $[7]0 $1 Class$format(7, [$2])  $format(9, 1C) ==> $left(36 $3)
}
on ^205 * {
	if ( rmatch($left($index([ $3)-1 $3) $_tn) == 1 )
		{ _trace_parse $0 $3 }
		{ _trace_serva $* }
if (trace) {echo $[7]0 $1 Class$format(7, [$2])  $format(9, 1C) ==> $left(36 $3)}
}
on ^206 * {_trace_serva $*;echo $[7]0 $1 Class$format(7, [$2]) $format(4, $3) $format(5, $4) ==> $stu($sname($5))$sip($5) 
}
alias _trace_serva {
	if ( rmatch($0 $_tn) == 1 )
		{ echo $_tt-$0 }
	assign -_tt
	assign -_tr
	assign _tn qwertyuiopzxc
}
alias _trace_parse assign _tr -$left($index([ $1)-1 $1);echo $_tt-$0$_tr$2;assign _tn qwertuipzxc;assign -_tr;assign -_tt
############
# Stores the output of a trace for use with conall
 
^alias storetrace {
    if (index([ $0)>-1) 
      { assign trace.$strip([].-0123456789*/ $0) $left($index([ $0) $0) }
      { assign trace.$strip([].-0123456789*/ $0) $0 }
}
 
^alias cleantr foreach trace ii { assign -trace[$ii] }
# connect to all the servers listed in the last trace
# food for when you restart the server.
^alias conall foreach trace ii { connect $trace[$ii] }
 
^alias format {
	@ IRCII.word = [$1-]
	if (@IRCII.word < [$0]) 
		{ @ function_return = [$([-$0]IRCII.word)] } 
		{ @ function_return = [$IRCII.word] } 
}
^alias lformat {
	@ IRCII.word = [$1-]
	if (@IRCII.word < [$0]) 
		{ @ function_return = [$([$0]IRCII.word)] } 
		{ @ function_return = [$IRCII.word] } 
}
 
 
# Trace information (extras')
# -----------------
# define RPL_TRACECONNECTING  201
^on ^201 * echo $[7]0 $1 Class$format(7, [$2]) trying...  ==> $[30]3-
 
# define RPL_TRACEHANDSHAKE   202
^on ^202 * echo $[7]0 $1 Class$format(7, [$2]) handshake  ==> $[30]3-
 
# define RPL_TRACEUNKNOWN     203
^on ^203 * echo $[7]0 $1 Class$format(7, [$2]) *unknown*  ==> $[30]3-
 
# define RPL_TRACESERVICE     207
^on ^207 * echo $[7]0 $1 Class[$format(7, $2)] service    ==> $[30]3-
 
# define RPL_TRACENEWTYPE     208
^on ^208 * echo $[7]0 $1 Class[$format(7, $2)] newtype    ==> $[30]3-
 
# define RPL_TRACECLASS       209
^on ^209 * echo $[7]0 -==- $1$format(7, [$2]) Entries linked: $3
 
################################
# STATS 
################################
# Stats information
# -----------------
 
# define RPL_STATSLINKINFO    211
^on ^211 * ^echo $stu($[40]1) $stu($left(19 $7-));echo $[10]2 $[10]3 $[10]4 $[10]5 $[7]6
^on ^211 "% *.*[*.*] *" $stu($[40]1) $stu($left(19 $7-));echo $[10]2 $[10]3 $[10]4 $[10]5 $[7]6
^on ^211 "% *[*" if (trace) {^echo $stu($[40]1) $stu($left(19 $7-));echo $[10]2 $[10]3 $[10]4 $[10]5 $[7]6}
 
# define RPL_STATSCOMMANDS    212
^on ^212 * ^echo $[7]0 $[10]1 :  $[-10]2 times 
 
# define RPL_STATSCLINE       213
^on ^213 * ^echo $[7]0 $1: $stu($[25]2):$3:$stu($[40]4):$5:$6-
 
# define RPL_STATSNLINE       214
^on ^214 * ^echo $[7]0 $1: $stu($[25]2):$3:$stu($[40]4):$5:$6-
 
# define RPL_STATSILINE       215
#^on ^215 * ^echo $[7]0 $1: $[25]2:$3: $[25]4:$5:$6-
 
# define RPL_STATSKLINE       216
#^on ^216 * ^echo $[7]0 $1: $[25]2:$3: $[25]4:$5:$6-
 
# define RPL_STATSQLINE      217
#^on ^217 * ^echo $[7]0 $1: $[25]2:$3: $[25]4:$5:$6-
 
# define RPL_STATSYLINE      218
^on ^218 * ^echo $[7]0 $1:$[5]2:$[5]3:$[5]4:$[5]5:$6-
 
# Return information on
# host masks being enforced locally.
#
^on ^220 * ^echo $[7]0 $1: $[25]2:$3: $[25]4:$5:$6-
 
# User Mode (2.1.5 actually knows about this. This is for 2.1.4e)
# define RPL_UMODEIS          221
^on ^221 * ^echo *** Your user mode is $1
 
# Service list:
^on ^231 * ^echo  $[7]0 Service $1 ($0)
########################################
# LINKS
########################################
alias links {
^assign -lcounter
^assign -lserver
^assign -lclass
@lcounter = 1
echo ***  No.   Class             Server                       Link
^on ^364 * {
^assign lserver $stu($1)
^assign lclass  $3
^assign llink $stu($2)
 echo *** \[$[-3]lcounter\]  \[$[-3]lclass\]  \[$[-25]lserver\] <-> \[$llink\]
 @lcounter = lcounter + 1
            }
//links $0
wait
^on ^364 -*
}
 
 
###########END OF STATS/LINKS/TRACE BEAUTIFIER